فيما يلي برنامج تعليمي لتحويل CSV إلى XLS أو XLSX باستخدام واجهة سطر الأوامر في Windows 10. هناك طرق متعددة لتحويل ملف CSV إلى تنسيقات Excel (XLS و XLSX). يمكنك استخدام Microsoft Excel ، أو برنامج تحويل مجاني مخصص ، أو أداة عبر الإنترنت لإجراء التحويل. ولكن ، هل تعلم أنه يمكنك أيضًا استخدام واجهة سطر أوامر Windows لتحويل CVS إلى Excel؟ وأنت لا تحتاج حتى إلى أي أداة خارجية لذلك؟ إذا لم يكن الأمر كذلك ، فسيكون هذا البرنامج التعليمي مفاجئًا لك.
في هذه المقالة ، سوف نوضح لك كيف يمكنك تحويل ملف CSV إلى مصنف Excel. لذلك ، سنستخدم VBScript. دعنا نتحقق من البرنامج النصي والخطوات التي تحتاجها للتحويل.
كيفية تحويل CSV إلى Excel باستخدام سطر الأوامر
فيما يلي خطوات تحويل CSV إلى Excel باستخدام واجهة سطر الأوامر في نظام التشغيل Windows 10:
- افتح المفكرة.
- اكتب برنامج Visual Basic (VBS).
- احفظ ملف VBS.
- افتح موجه الأوامر في المجلد.
- أدخل أمر تحويل CSV إلى Excel.
دعونا نناقش هذه الخطوات بالتفصيل!
أولاً ، افتح تطبيق Notepad على جهاز الكمبيوتر الذي يعمل بنظام Windows 10. عليك الآن كتابة VBScript مع الأوامر ذات الصلة. يوجد أدناه البرنامج النصي الكامل الذي تحتاج إلى إدخاله في المفكرة ؛ فقط قم بنسخه من هنا ولصقه في المفكرة الخاصة بك:
'======================================
' Convert CSV to Excel
'
' arg1: source - CSV path\file
' arg2: target - Excel path\file
'======================================
srccsvfile = Wscript.Arguments(0)
tgtxlsfile = Wscript.Arguments(1)
'Create Spreadsheet
'Look for an existing Excel instance.
On Error Resume Next ' Turn on the error handling flag
Set objExcel = GetObject(,"Excel.Application")
'If not found, create a new instance.
If Err.Number = 429 Then '> 0
Set objExcel = CreateObject("Excel.Application")
End If
objExcel.Visible = false
objExcel.displayalerts=false
'Import CSV into Spreadsheet
Set objWorkbook = objExcel.Workbooks.open(srccsvfile)
Set objWorksheet1 = objWorkbook.Worksheets(1)
'Adjust width of columns
Set objRange = objWorksheet1.UsedRange
objRange.EntireColumn.Autofit()
'This code could be used to AutoFit a select number of columns
'For intColumns = 1 To 17
' objExcel.Columns(intColumns).AutoFit()
'Next
'Make Headings Bold
objExcel.Rows(1).Font.Bold = TRUE
'Freeze header row
With objExcel.ActiveWindow
.SplitColumn = 0
.SplitRow = 1
End With
objExcel.ActiveWindow.FreezePanes = True
'Add Data Filters to Heading Row
objExcel.Rows(1).AutoFilter
'set header row gray
objExcel.Rows(1).Interior.ColorIndex = 15
'-0.249977111117893
'Save Spreadsheet, 51 = Excel 2007-2010
objWorksheet1.SaveAs tgtxlsfile, 51
'Release Lock on Spreadsheet
objExcel.Quit()
Set objWorksheet1 = Nothing
Set objWorkbook = Nothing
Set ObjExcel = Nothing
بعد إدخال البرنامج النصي أعلاه ، تحتاج إلى حفظ الملف بامتداد الملف .vbs . لذلك ، انقر فوق ملف> حفظ باسم الخيار. في موجه الحوار Save As ، عيّن Save As Type على All Files ثم أدخل اسم الملف متبوعًا بامتداد الملف .vbs. بعد ذلك ، انقر فوق الزر حفظ لحفظ ملف VBS.
الآن ، انتقل إلى المجلد حيث قمت بحفظ برنامج VBS أعلاه وافتح موجه الأوامر في هذا المجلد .
بعد ذلك ، يجب عليك إدخال أمر بالصيغة أدناه في CMD:
VBSFilename [Input CSV file with path] [Output Excel file with path]
لنفترض أنك قمت بتسمية ملف VBS باسم “csv-to-excel” ، ثم سيبدو الأمر الخاص بك مثل الأمر التالي:
csv-to-excel C:\Users\KOMAL\Desktop\twc.csv C:\Users\KOMAL\Desktop\twc1.xlsx
إذا كنت ترغب في إنشاء ملف Excel بامتداد الملف الأقدم ، مثل XLS ، فما عليك سوى استبدال xlsx بـ xls . هنا مثال:
csv-to-excel C:\Users\KOMAL\Desktop\twc.csv C:\Users\KOMAL\Desktop\twc1.xls
تذكر أنه يجب عليك ذكر المسار الكامل لكل من إدخال ملفات CSV وملفات Excel الناتجة.
عند إدخال الأمر أعلاه ، ستحصل على ملف Excel الناتج.
في VBScript أعلاه ، هناك خيارات لضبط عرض العمود ، وجزء التجميد ، وتطبيق عامل التصفية ، وجعل الرأس غامقًا ، وما إلى ذلك. يمكنك بسهولة تعديل VBScript لتخصيص هذه الخيارات ثم تشغيل الأمر لتحويل CSV إلى Excel من خلال CMD. إذا كنت مبرمجًا ، فيمكنك تخصيص البرنامج النصي بشكل أكبر وفقًا لذلك.
